; Cover_Taskbar_Borders_and_Side_Panel_Borders--
; Script_for_use_with_a_Windows_classic_theme.ahk
; 
; v1.0 - Completed 10/4/2011.
; 
; A heavily-modified derivative of DimScreen.ahk.  
;
; The modifications were done by Apollia of Astroblahhh.Com.
;
; The original DimScreen.ahk is by Skrommel.
;
;
; You can download this Cover_Taskbar_Borders_and_Side_Panel_Borders 
; script somewhere around here:
;
; http://astroblahhh.com/windows.shtml
;
;
; The original DimScreen.ahk is available here:
; http://www.donationcoder.com/Software/Skrommel/index.html#DimScreen
;
;
; This script is intended for Windows.  I've tested it in Windows XP.
;
; It might work with any version of Windows which allows you to use
; the Windows Classic themes.
;
;
; The purpose of this script
;
; When I'm using Windows XP, I like to use a dark Windows Classic
; theme based on High Contrast Black - but unfortunately, the dark 
; high-contrast themes all have bright white borders everywhere 
; that I don't know how to get rid of.
;
; So, I finally decided to eliminate a small portion of the problem 
; using a simple AHK script to cover the top and bottom borders of 
; the taskbar, and also the borders at the left and right of my 
; screen from the pop-up side panels I use, and from maximized
; windows.
;
;
; Instructions
;
; To make your computer capable of running this script, install 
; AutoHotkey Basic from: http://www.autohotkey.com/download/
;
; (I don't know if AutoHotkey_L will run it properly - haven't
; tested it, but it might work.)
; 
; Once you install AutoHotkey Basic, you'll be able to run this
; script just by double-clicking on it.
;
; If you want to remove the covers momentarily, double-click the 
; script's taskbar icon.  To restore them, double-click it again. 
;
;
; You can edit the source code to adjust the size and placement of
; the covers.  You can also choose custom taskbar icons to use.
;
; More details on how to do those things are in comments next to the 
; parts you should change.


#SingleInstance,Force
#NoEnv
SetWinDelay,0


;******************* Start of settings you can adjust

	; If you set the below values wrong and this script's taskbar icon 
	; gets covered and you can't find it so you can end the script, you 
	; can kill the script using the Task Manager.
	;
	; In Windows XP, you can open the Task Manager by pressing 
	; Ctrl-Alt-Delete.
	;
	; If you're running this as an .ahk script, the process to kill will 
	; be AutoHotkey.exe.
	;
	; If you made this .ahk script into an .exe file, the process to 
	; kill will have the name you gave the .exe file.
	;
	; In the Task Manager, go to the Processes tab, highlight the 
	; appropriate process, and either right-click it and choose End 
	; Process, or press the End Process button.

Use_Upper_Cover_for_Taskbar=true
Use_Lower_Cover_for_Taskbar=true
Use_Left_Cover=true
Use_Right_Cover=true
	; Set to false if you'd rather not have some of the above covers.
	
Top_of_Upper_Cover_for_Taskbar__Distance_from_Bottom_of_Screen=32
	; Original setting: 32
	
Thickness_of_Upper_Cover_for_Taskbar=8
	; Original setting: 8
	
Thickness_of_Lower_Cover_for_Taskbar=4
	; Original setting: 4

Left_Cover_Thickness=7
	; Original setting: 7
	
Right_Cover_Thickness=7
	; Original setting: 7

; I made the covers for the left, right, and upper part of the taskbar
; a little larger than they had to be so they would also cover the 
; borders of maximized windows.


Tray_Icon_Path_or_File_Name__Shown_When_Cover_On=Button-Blank-Green.ico
Tray_Icon_Path_or_File_Name__Shown_When_Cover_Off=
	; If you'd like the tray icon to be different from the default,
	; you can set one or both of the above variables.
	;
	; Leaving them blank is fine too.
	;
	; If you just put a file name instead of a file path,
	; the icon files have to be in the same directory as the
	; script.
	;
	; Example of a file path in a valid format:
	;	X:\Depot\Button-Blank-Green.ico
	;
	; The icons must be in .ico format.  
	;
	; There are tons of icons at:
	;  http://iconarchive.org/



; ************ End of settings you can adjust


; ************ Nothing else needs to be changed.


AbsoluteBottom:= A_ScreenHeight

Upper_Cover_for_Taskbar__Y_Start := AbsoluteBottom - Top_of_Upper_Cover_for_Taskbar__Distance_from_Bottom_of_Screen

Lower_Cover_for_Taskbar__Y_Start := AbsoluteBottom - Thickness_of_Lower_Cover_for_Taskbar

Right_Cover__X_Start := A_ScreenWidth-Right_Cover_Thickness


applicationname=Cover Taskbar Borders and Side Panel Borders
appversion = 1.0


Gosub,MENU
Gosub,MAKE_COVERS


LOOP:
WinGet,id,Id,A
Gosub, ALL_ON_TOP
WinWaitNotActive,ahk_id %id%
Goto,LOOP


ALL_ON_TOP:
if Use_Upper_Cover_for_Taskbar=true
{	
	WinSet,AlwaysOnTop,On,ahk_id %guiid%
}
if Use_Lower_Cover_for_Taskbar=true
{	
	WinSet,AlwaysOnTop,On,ahk_id %guiid3%
}
if Use_Left_Cover=true
{	
	WinSet,AlwaysOnTop,On,ahk_id %guiid4%
}
if Use_Right_Cover=true
{	
	WinSet,AlwaysOnTop,On,ahk_id %guiid5%
}
Return

ALL_SHOWN:
if Use_Upper_Cover_for_Taskbar=true
{	
	WinSet,Transparent,255,ahk_id %guiid%
}
if Use_Lower_Cover_for_Taskbar=true
{	
	WinSet,Transparent,255,ahk_id %guiid3%
}
if Use_Left_Cover=true
{	
	WinSet,Transparent,255,ahk_id %guiid4%
}
if Use_Right_Cover=true
{
	WinSet,Transparent,255,ahk_id %guiid5%
}
Return

ALL_HIDDEN:
if Use_Upper_Cover_for_Taskbar=true
{
	WinSet,Transparent,0,ahk_id %guiid%
}
if Use_Lower_Cover_for_Taskbar=true
{
	WinSet,Transparent,0,ahk_id %guiid3%
}
if Use_Left_Cover=true
{
	WinSet,Transparent,0,ahk_id %guiid4%
}
if Use_Right_Cover=true
{
	WinSet,Transparent,0,ahk_id %guiid5%
}
Return


HIDE_OR_SHOW_COVERS:

if (hidden="yes")
{	
	GoSub, ALL_SHOWN
	GoSub, ALL_ON_TOP
	
	hidden:="no"
	IfExist, %Tray_Icon_Path_or_File_Name__Shown_When_Cover_On%
	{
		Menu,Tray,Icon,%Tray_Icon_Path_or_File_Name__Shown_When_Cover_On%
	}
}
else if (hidden="no")
{	
	GoSub, ALL_HIDDEN
	GoSub, ALL_ON_TOP
	hidden:="yes"
	IfExist, %Tray_Icon_Path_or_File_Name__Shown_When_Cover_Off%
	{
		Menu,Tray,Icon,%Tray_Icon_Path_or_File_Name__Shown_When_Cover_Off%
	}
	
}
Return


MAKE_COVERS:

;Gui - Upper cover for taskbar

if Use_Upper_Cover_for_Taskbar=true
{
	Gui,+ToolWindow -Disabled -SysMenu -Caption +E0x20 +AlwaysOnTop 
	Gui,Color,000000

	Gui,Show,% "X0 Y" . Upper_Cover_for_Taskbar__Y_Start . "W" . A_ScreenWidth "H" . Thickness_of_Upper_Cover_for_Taskbar,%applicationname% Screen

	Gui,+LastFound
	WinGet,guiid,Id,A
}


;Gui3 - Lower cover for taskbar
if Use_Lower_Cover_for_Taskbar=true
{		
	Gui, 3:+ToolWindow -Disabled -SysMenu -Caption +E0x20 +AlwaysOnTop 
	Gui, 3:Color,000000

	Gui, 3:Show,% "X0 Y" . Lower_Cover_for_Taskbar__Y_Start . "W" . A_ScreenWidth "H" . Thickness_of_Lower_Cover_for_Taskbar,%applicationname% Screen

	Gui, 3:+LastFound
	WinGet,guiid3,Id,A
}


;Gui4 - Left edge cover
if Use_Left_Cover=true
{
	Gui, 4:+ToolWindow -Disabled -SysMenu -Caption +E0x20 +AlwaysOnTop 
	Gui, 4:Color,000000

	Gui, 4:Show,% "X0 Y0 W" . Left_Cover_Thickness "H" . AbsoluteBottom,%applicationname% Screen

	Gui, 4:+LastFound
	WinGet,guiid4,Id,A
}


;Gui5 - Right edge cover
if Use_Right_Cover=true
{
	Gui, 5:+ToolWindow -Disabled -SysMenu -Caption +E0x20 +AlwaysOnTop 
	Gui, 5:Color,000000

	Gui, 5:Show,% "X" . Right_Cover__X_Start . "Y0 W" . Right_Cover_Thickness "H" . AbsoluteBottom,%applicationname% Screen

	Gui, 5:+LastFound
	WinGet,guiid5,Id,A
}

;*********

hidden:="no"
GOSUB, ALL_SHOWN
Return


MENU:
Menu,Tray,DeleteAll
IfExist, %Tray_Icon_Path_or_File_Name__Shown_When_Cover_On%
{
	Menu,Tray,Icon,%Tray_Icon_Path_or_File_Name__Shown_When_Cover_On%
}
Menu,Tray,NoStandard
Menu,Tray,Add,Hide or Show Covers, HIDE_OR_SHOW_COVERS
Menu,Tray,Default,Hide or Show Covers
Menu,Tray,Add,
Menu,Tray,Add,&About...,ABOUT
Menu,Tray,Add,&Exit,EXIT
Menu,Tray,Tip,%applicationname% %appversion%
Return


ABOUT:
Gui,2:Destroy
Gui,2:Margin,10,10
Gui,2:Font,Bold
Gui,2:Add,Text,x+10 yp+10,%applicationname% v%appversion%
Gui,2:Font
Gui,2:Add,Text,y+10,A heavily-modified derivative of DimScreen.ahk.

Gui,2:Add,Text,xp y+15,The modifications were done by Apollia of Astroblahhh.Com.
Gui,2:Add,Text,xp y+5,The original DimScreen.ahk is by Skrommel.

Gui,2:Add,Text,xp y+25,If you're using a Windows Classic theme, %applicationname% 
Gui,2:Add,Text,xp y+5,covers the top and bottom borders of your taskbar, and also the borders
Gui,2:Add,Text,xp y+5,at the left and right of your screen from maximized windows,  
Gui,2:Add,Text,xp y+5,or from pop-up side panels you've set up.

Gui,2:Add,Text,xp y+20, The reason I (Apollia) made this is because the dark high contrast Windows classic

Gui,2:Add,Text,xp y+5, themes have annoying bright white borders everywhere.

Gui,2:Add,Picture,xm y+20 Icon6,%applicationname%.exe
Gui,2:Font,Bold
Gui,2:Add,Text,x+10 yp+10,Astroblahhh.Com
Gui,2:Font
Gui,2:Add,Text,y+10, Apollia's home page with lots of different stuff.
Gui,2:Font,CBlue Underline
Gui,2:Add,Text,y+5 GASTROBLAHHH,Astroblahhh.Com
Gui,2:Font

Gui,2:Add,Text,xp y+35,Links Apollia highly recommends:

Gui,2:Add,Picture,xm y+10 Icon2,%applicationname%.exe
Gui,2:Font,Bold
Gui,2:Add,Text,x+10 yp+10,1 Hour Software by Skrommel
Gui,2:Font
Gui,2:Add,Text,y+10,For more tools, information and donations, please visit 
Gui,2:Font,CBlue Underline
Gui,2:Add,Text,y+5 G1HOURSOFTWARE,www.1HourSoftware.com
Gui,2:Font

Gui,2:Add,Picture,xm y+20 Icon7,%applicationname%.exe
Gui,2:Font,Bold
Gui,2:Add,Text,x+10 yp+10,DonationCoder
Gui,2:Font
Gui,2:Add,Text,y+10,Please support the contributors at
Gui,2:Font,CBlue Underline
Gui,2:Add,Text,y+5 GDONATIONCODER,www.DonationCoder.com
Gui,2:Font

Gui,2:Add,Picture,xm y+20 Icon6,%applicationname%.exe
Gui,2:Font,Bold
Gui,2:Add,Text,x+10 yp+10,AutoHotkey
Gui,2:Font
Gui,2:Add,Text,y+10,This tool was made using the powerful
Gui,2:Font,CBlue Underline
Gui,2:Add,Text,y+5 GAUTOHOTKEY,www.AutoHotkey.com
Gui,2:Font
Gui,2:Add,Button,x187 y+20 w75 Default gABOUTOK,&OK

Gui,2:Show,,%applicationname% - About

Return


1HOURSOFTWARE:
Run,http://www.1hoursoftware.com,,UseErrorLevel
Return

DONATIONCODER:
Run,http://www.donationcoder.com,,UseErrorLevel
Return

AUTOHOTKEY:
Run,http://www.autohotkey.com,,UseErrorLevel
Return

ASTROBLAHHH:
Run,http://astroblahhh.com,,UseErrorLevel
Return

ABOUTOK:
Gui,2:Destroy
Return


EXIT:
ExitApp